ເນື້ອໃນ

# ຟັງຊັນ AVERAGEIF

ສົ່ງຄືນຄ່າສະເລ່ຍເລກຄະນິດຂອງທຸກໆເຊວໃນຊ່ວງທີ່ກົງກັບເງື່ອນໄຂທີ່ກຳນົດໃຫ້. ຟັງຊັນ AVERAGEIF ຈະລວມຄ່າທັງໝົດທີ່ກົງກັບການທົດສອບທາງຕັກກະສາດ ແລະ ຫານຜົນລວມນັ້ນດ້ວຍຈຳນວນຄ່າທີ່ເລືອກ.

ຟັງຊັນນີ້ມີໃຫ້ໃຊ້ຕັ້ງແຕ່ LibreOfficeDev 4.0.

### ໄວຍາກອນ

=AVERAGEIF(Range; Criterion [; Average_Range ])

Range – ອາກິວເມັນທີ່ຈຳເປັນ. ອາເຣ, ຊື່ຂອງຊ່ວງທີ່ຕັ້ງຊື່ໄວ້ ຫຼື ປ້າຍຊື່ຂອງຄໍລຳ ຫຼື ແຖວທີ່ມີຕົວເລກສຳລັບການຫາຄ່າສະເລ່ຍ ຫຼື ຕົວເລກ ຫຼື ຂໍ້ຄວາມສຳລັບເງື່ອນໄຂ.

Criterion1: ເງື່ອນໄຂແມ່ນນິພົດຂໍ້ຄວາມທີ່ຄຳນວນຈາກການອ້າງອີງຫ້ອງດຽວ, ສູດ, ຕົວເລກ ຫຼື ຂໍ້ຄວາມ. ມັນຖືກໃຊ້ໃນການປຽບທຽບກັບເນື້ອໃນຂອງຫ້ອງ.

ການອ້າງອີງເຖິງຫ້ອງວ່າງຈະຖືກຕີຄວາມໝາຍເປັນຄ່າຕົວເລກ 0.

ນິພົດທີ່ກົງກັນສາມາດເປັນ:

- ຕົວເລກ ຫຼື ຄ່າທາງຕັກກະສາດ. ເນື້ອໃນຫ້ອງທີ່ກົງກັນຈະເທົ່າກັບຕົວເລກ ຫຼື ຄ່າທາງຕັກກະສາດນັ້ນ.

- ຄ່າທີ່ເລີ່ມຕົ້ນດ້ວຍຕົວປຽບທຽບ (<, <=, =, >, >=, <>).

  ສຳລັບ =, ຖ້າຄ່າວ່າງ ມັນຈະກົງກັບຫ້ອງທີ່ວ່າງ.

  ສຳລັບ <>, ຖ້າຄ່າວ່າງ ມັນຈະກົງກັບຫ້ອງທີ່ບໍ່ວ່າງ.

  ສຳລັບ <>, ຖ້າຄ່າບໍ່ວ່າງ ມັນຈະກົງກັບເນື້ອໃນຫ້ອງໃດກໍໄດ້ຍົກເວັ້ນຄ່ານັ້ນ, ລວມທັງຫ້ອງວ່າງນຳ.

  ໝາຍເຫດ: "=0" ບໍ່ກົງກັບຫ້ອງວ່າງ.

  ສຳລັບ = ແລະ <>, ຖ້າຄ່າບໍ່ວ່າງ ແລະ ບໍ່ສາມາດຕີຄວາມໝາຍເປັນປະເພດຕົວເລກໄດ້ ແລະ ມີການເລືອກຄຸນສົມບັດ ເງື່ອນໄຂການຄົ້ນຫາ = ແລະ <> ຕ້ອງໃຊ້ກັບທັງໝົດຫ້ອງ, ການປຽບທຽບຈະເຮັດກັບເນື້ອໃນທັງໝົດຂອງຫ້ອງ. ຖ້າບໍ່ໄດ້ເລືອກ, ການປຽບທຽບຈະເຮັດກັບສ່ວນໃດສ່ວນໜຶ່ງຂອງຊ່ອງຂໍ້ມູນທີ່ກົງກັບເງື່ອນໄຂ.

- ຄ່າຂໍ້ຄວາມອື່ນໆ. ຖ້າຄຸນສົມບັດ ເງື່ອນໄຂການຄົ້ນຫາ = ແລະ <> ຕ້ອງໃຊ້ກັບທັງໝົດຫ້ອງ ເປັນຈິງ, ການປຽບທຽບຈະເຮັດກັບເນື້ອໃນທັງໝົດຂອງຫ້ອງ. ຖ້າເປັນເທັດ, ການປຽບທຽບຈະເຮັດກັບສ່ວນໃດສ່ວນໜຶ່ງຂອງຊ່ອງຂໍ້ມູນທີ່ກົງກັບເງື່ອນໄຂ. ນິພົດສາມາດປະກອບດ້ວຍຂໍ້ຄວາມ, ຕົວເລກ, ນິພົດປົກກະຕິ (Regular expressions) ຫຼື ຕົວແທນ (Wildcards) (ຖ້າເປີດໃຊ້ໃນຕົວເລືອກການຄຳນວນ).

ການຄົ້ນຫາຮອງຮັບຕົວແທນ (wildcards) ຫຼື ນິພົດປົກກະຕິ (regular expressions). ເມື່ອເປີດໃຊ້ນິພົດປົກກະຕິ, ທ່ານສາມາດປ້ອນ "all.*", ຕົວຢ່າງເພື່ອຊອກຫາຕຳແໜ່ງທຳອິດຂອງ "all" ທີ່ຕາມດ້ວຍຕົວອັກສອນໃດໆ. ຖ້າທ່ານຕ້ອງການຄົ້ນຫາຂໍ້ຄວາມທີ່ເປັນນິພົດປົກກະຕິຄືກັນ, ທ່ານຕ້ອງໃສ່ເຄື່ອງໝາຍ "\" ໄວ້ໜ້າທຸກຕົວອັກສອນພິເສດ ຫຼື ຕົວດຳເນີນການຂອງນິພົດປົກກະຕິ, ຫຼື ກວມເອົາຂໍ້ຄວາມນັ້ນໄວ້ໃນ \Q...\E. ທ່ານສາມາດເປີດ ຫຼື ປິດການປະເມີນອັດຕະໂນມັດຂອງຕົວແທນ ຫຼື ນິພົດປົກກະຕິໄດ້ທີ່ LibreOfficeDev - ຄວາມມັກເຄື່ອງມື - ຕົວເລືອກ - LibreOfficeDev Calc - ຄິດໄລ່.

ເມື່ອໃຊ້ຟັງຊັນທີ່ມີອາຄິວເມັ້ນ (argument) ໜຶ່ງ ຫຼື ຫຼາຍກວ່າເປັນຂໍ້ຄວາມເງື່ອນໄຂການຄົ້ນຫາທີ່ສະແດງເຖິງນິພົດປົກກະຕິ, ມັນຈະພະຍາຍາມແປງຂໍ້ຄວາມເງື່ອນໄຂນັ້ນໃຫ້ເປັນຕົວເລກກ່ອນ. ຕົວຢ່າງ, ".0" ຈະຖືກແປງເປັນ 0.0 ແລະ ອື່ນໆ. ຖ້າສຳເລັດ, ການຈັບຄູ່ຈະບໍ່ແມ່ນການຈັບຄູ່ແບບນິພົດປົກກະຕິ ແຕ່ຈະເປັນການຈັບຄູ່ແບບຕົວເລກ. ແນວໃດກໍຕາມ, ເມື່ອປ່ຽນໄປໃຊ້ທ້ອງຖິ່ນ (locale) ທີ່ຕົວຂັ້ນທົດສະນິຍົມບໍ່ແມ່ນຈຸດ ຈະເຮັດໃຫ້ການແປງນິພົດປົກກະຕິເຮັດວຽກໄດ້. ເພື່ອບັງຄັບໃຫ້ມີການປະເມີນເປັນນິພົດປົກກະຕິແທນການສະແດງຜົນແບບຕົວເລກ, ໃຫ້ໃຊ້ບາງນິພົດທີ່ບໍ່ສາມາດຖືກອ່ານຜິດເປັນຕົວເລກໄດ້ ເຊັ່ນ ".[0]" ຫຼື ".\0" ຫຼື "(?i).0".

Average_Range – ທາງເລືອກ. ມັນແມ່ນຊ່ວງຂອງຄ່າສຳລັບການຄິດໄລ່ຄ່າສະເລ່ຍ.

ຖ້າບໍ່ໄດ້ກຳນົດ Average_Range, ຈະໃຊ້ Range ສຳລັບທັງການຄິດໄລ່ຄ່າສະເລ່ຍ ແລະ ການຄົ້ນຫາຕາມເງື່ອນໄຂ. ຖ້າກຳນົດ Average_Range, ຈະໃຊ້ Range ສະເພາະສຳລັບການທົດສອບເງື່ອນໄຂເທົ່ານັ້ນ, ໃນຂະນະທີ່ Average_Range ຈະຖືກໃຊ້ເພື່ອຄິດໄລ່ຄ່າສະເລ່ຍ.

ຖ້າເຊວໃນຊ່ວງຄ່າສຳລັບຄິດໄລ່ຄ່າສະເລ່ຍວ່າງເປົ່າ ຫຼື ມີຂໍ້ຄວາມ, ຟັງຊັນ AVERAGEIF ຈະລະເວັ້ນເຊວນັ້ນ.
ຖ້າທັງຊ່ວງວ່າງເປົ່າ, ມີແຕ່ຂໍ້ຄວາມ ຫຼື ທຸກໆຄ່າໃນຊ່ວງບໍ່ກົງກັບເງື່ອນໄຂ, ຟັງຊັນຈະສົ່ງຄືນຂໍ້ຜິດພາດ #DIV/0!.

### ຕົວຢ່າງ

ພິຈາລະນາຕາຕະລາງຕໍ່ໄປນີ້

| A | B | C
1 | ຊື່ຜະລິດຕະພັນ | Sales | Revenue
2 | ສໍດຳ | 20 | 65
3 | ບິກ | 35 | 85
4 | ປຶ້ມບັນທຶກ | 20 | 190
5 | ປຶ້ມ | 17 | 180
6 | ກະເປົ໋າສໍ | ບໍ່ແມ່ນ | ບໍ່ແມ່ນ

ໃນທຸກຕົວຢ່າງລຸ່ມນີ້, ຊ່ວງສຳລັບການຄຳນວນປະກອບມີແຖວທີ 6, ເຊິ່ງຈະຖືກລະເວັ້ນເນື່ອງຈາກມັນປະກອບດ້ວຍຂໍ້ຄວາມ.

#### ການນຳໃຊ້ແບບງ່າຍດາຍ

=AVERAGEIF(B2:B6;"<35")

ຄິດໄລ່ຄ່າສະເລ່ຍສຳລັບຄ່າໃນຊ່ວງ B2:B6 ທີ່ໜ້ອຍກວ່າ 35. ສົ່ງຄືນ 19, ຍ້ອນວ່າແຖວທີສອງບໍ່ໄດ້ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

=AVERAGEIF(B2:B6;"<"&MAX(B2:B6))

ຄິດໄລ່ຄ່າສະເລ່ຍສຳລັບຄ່າໃນຊ່ວງດຽວກັນທີ່ໜ້ອຍກວ່າຄ່າສູງສຸດຂອງຊ່ວງນີ້. ສົ່ງຄືນ 19, ຍ້ອນວ່າຄ່າທີ່ໃຫຍ່ທີ່ສຸດ (ແຖວທີສອງ) ບໍ່ໄດ້ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

=AVERAGEIF(B2:B6;">"&SMALL(B2:B6;1))

ຄິດໄລ່ຄ່າສະເລ່ຍສຳລັບຄ່າໃນຊ່ວງດຽວກັນທີ່ໃຫຍ່ກວ່າຄ່ານ້ອຍທີ່ສຸດລຳດັບທີໜຶ່ງຂອງຊ່ວງນີ້. ສົ່ງຄືນ 25, ຍ້ອນວ່າຄ່ານ້ອຍທີ່ສຸດລຳດັບທີໜຶ່ງ (ແຖວທີສີ່) ບໍ່ໄດ້ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

#### ການນຳໃຊ້ Average_Range

=AVERAGEIF(B2:B6;"<35";C2:C6)

ຟັງຊັນຈະຄົ້ນຫາວ່າຄ່າໃດໜ້ອຍກວ່າ 35 ໃນຊ່ວງ B2:B6, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ C2:C6. ສົ່ງຄືນ 145, ຍ້ອນວ່າແຖວທີສອງບໍ່ໄດ້ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

=AVERAGEIF(B2:B6;">"&MIN(B2:B6);C2:C6)

ຟັງຊັນຈະຄົ້ນຫາວ່າຄ່າໃດໃນຊ່ວງ B2:B6 ທີ່ໃຫຍ່ກວ່າຄ່ານ້ອຍທີ່ສຸດໃນຊ່ວງ B2:B6, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ C2:C6. ສົ່ງຄືນ 113.3, ຍ້ອນວ່າແຖວທີສີ່ (ບ່ອນທີ່ມີຄ່ານ້ອຍທີ່ສຸດ) ບໍ່ໄດ້ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

=AVERAGEIF(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)

ຟັງຊັນຈະຄົ້ນຫາວ່າຄ່າໃດໃນຊ່ວງ B2:B6 ທີ່ໜ້ອຍກວ່າຄ່າໃຫຍ່ທີ່ສຸດລຳດັບທີສອງໃນຊ່ວງ B2:B6, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ C2:C6. ສົ່ງຄືນ 180, ຍ້ອນວ່າມີພຽງແຖວທີສີ່ເທົ່ານັ້ນທີ່ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

#### ການນຳໃຊ້ Regular Expressions

=AVERAGEIF(A2:A6;"pen";B2:B6)

ຟັງຊັນຈະຄົ້ນຫາວ່າເຊວໃດໃນຊ່ວງ A2:A6 ທີ່ມີແຕ່ຄຳວ່າ “pen”, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ B2:B6. ສົ່ງຄືນ 35, ຍ້ອນວ່າມີພຽງແຖວທີສອງເທົ່ານັ້ນທີ່ຖືກລວມເຂົ້າໃນການຄິດໄລ່. ການຄົ້ນຫາແມ່ນເຮັດໃນຊ່ວງ A2:A6, ແຕ່ຄ່າແມ່ນໄດ້ມາຈາກຊ່ວງ B2:B6.

=AVERAGEIF(A2:A6;"pen.*";B2:B6)

ຟັງຊັນຈະຄົ້ນຫາວ່າເຊວໃດໃນຊ່ວງ A2:A6 ທີ່ຂຶ້ນຕົ້ນດ້ວຍ “pen” ແລະ ຕາມດ້ວຍຕົວອັກສອນອື່ນໆ, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ B2:B6. ສົ່ງຄືນ 27.5, ຍ້ອນວ່າໃນຕອນນີ້ “pencil” ກໍກົງກັບເງື່ອນໄຂຄືກັນ, ເຮັດໃຫ້ທັງແຖວທີໜຶ່ງ ແລະ ແຖວທີສອງຖືກລວມເຂົ້າໃນການຄິດໄລ່.

=AVERAGEIF(A2:A6;".*book.*";B2:B6)

ຟັງຊັນຈະຄົ້ນຫາວ່າເຊວໃດໃນຊ່ວງ A2:A6 ທີ່ມີຄຳວ່າ “book” ຢູ່ພາຍໃນ, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ B2:B6. ສົ່ງຄືນ 18.5, ຍ້ອນວ່າມີພຽງແຖວທີສາມ ແລະ ແຖວທີສີ່ເທົ່ານັ້ນທີ່ຖືກລວມເຂົ້າໃນການຄິດໄລ່.

#### ການອ້າງອີງໃສ່ເຊວເປັນເກນເງື່ອນໄຂ

ຖ້າທ່ານຕ້ອງການປ່ຽນເກນເງື່ອນໄຂໄດ້ງ່າຍ, ທ່ານສາມາດກຳນົດມັນໄວ້ໃນເຊວແຍກຕ່າງຫາກ ແລະ ໃຊ້ການອ້າງອີງໃສ່ເຊວນັ້ນໃນເງື່ອນໄຂຂອງຟັງຊັນ AVERAGEIF.

=AVERAGEIF(A2:A6;".*"&E2&".*";B2:B6)

ຟັງຊັນຈະຄົ້ນຫາວ່າເຊວໃດໃນຊ່ວງ A2:A6 ທີ່ມີຂໍ້ຄວາມຕາມທີ່ກຳນົດໃນ E2, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ B2:B6. ຖ້າ E2 = book, ຟັງຊັນຈະສົ່ງຄືນ 18.5.

=AVERAGEIF(B2:B6;"<"&E2;C2:C6)

ຟັງຊັນຈະຄົ້ນຫາວ່າເຊວໃດໃນຊ່ວງ B2:B6 ທີ່ມີຄ່ານ້ອຍກວ່າຄ່າທີ່ກຳນົດໃນ E2, ແລະ ຄິດໄລ່ຄ່າສະເລ່ຍຂອງຄ່າທີ່ກົງກັນຈາກຊ່ວງ C2:C6. ຖ້າ E2 = 35, ຟັງຊັນຈະສົ່ງຄືນ 145.

#### ຂໍ້ມູນທາງເຕັກນິກ

ຟັງຊັນນີ້ເປັນສ່ວນໜຶ່ງຂອງມາດຕະຖານ Open Document Format for Office Applications (OpenDocument) ເວີຊັນ 1.2. (ISO/IEC 26300:2-2015)

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ໜ້າວິີກີ AVERAGEIF.

AVERAGE, AVERAGEA, AVEDEV

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

ລາຍຊື່ຂອງນິພົດປົກກະຕິ

ກະລຸນາສະໜັບສະໜູນພວກເຮົາ!