ເນື້ອໃນ

# ຟັງຊັນ AGGREGATE

ຟັງຊັນນີ້ສົ່ງຄືນຜົນສັງລວມຂອງການຄຳນວນໃນຊ່ວງຂໍ້ມູນ. ທ່ານສາມາດໃຊ້ຟັງຊັນການສັງລວມຕ່າງໆທີ່ລະບຸໄວ້ລຸ່ມນີ້. ຟັງຊັນ Aggregate ຊ່ວຍໃຫ້ທ່ານສາມາດລະເວັ້ນແຖວທີ່ເຊື່ອງໄວ້, ຂໍ້ຜິດພາດ, ຜົນຂອງ SUBTOTAL ແລະ ຜົນຂອງຟັງຊັນ AGGREGATE ອື່ນໆ ໃນການຄຳນວນໄດ້.

ຟັງຊັນ AGGREGATE ຖືກນຳໃຊ້ກັບຊ່ວງຂໍ້ມູນໃນແນວຕັ້ງທີ່ມີການເປີດໃຊ້ AutoFilter. ຖ້າບໍ່ໄດ້ເປີດໃຊ້ AutoFilter, ການຄຳນວນຜົນຄືນໃໝ່ໂດຍອັດຕະໂນມັດຈະບໍ່ເຮັດວຽກສຳລັບແຖວທີ່ຖືກເຊື່ອງໃໝ່. ຟັງຊັນນີ້ບໍ່ໄດ້ຖືກອອກແບບມາໃຫ້ໃຊ້ກັບຊ່ວງຂໍ້ມູນໃນແນວນອນ, ແຕ່ກໍສາມາດນຳໃຊ້ໄດ້ໂດຍມີຂໍ້ຈຳກັດ. ໂດຍສະເພາະແມ່ນ ຟັງຊັນ AGGREGATE ທີ່ໃຊ້ກັບຊ່ວງຂໍ້ມູນແນວນອນຈະບໍ່ຮັບຮູ້ການເຊື່ອງຖັນ, ແຕ່ຈະລະເວັ້ນຂໍ້ຜິດພາດ ແລະ ຜົນຂອງ SUBTOTAL ຫຼື ຟັງຊັນ AGGREGATE ອື່ນໆທີ່ຝັງຢູ່ໃນແຖວນັ້ນໄດ້ຢ່າງຖືກຕ້ອງ.

### ໄວຍາກອນ

AGGREGATE(Function; Option; Number 1[; Number 2][; ... ;[Number 253]])

ຫຼື

AGGREGATE(Function; Option; Array[; k])

Function – ພາຣາມິເຕີທີ່ຈຳເປັນ. ແມ່ນດັດສະນີຟັງຊັນ ຫຼື ການອ້າງອີງເຖິງຫ້ອງທີ່ມີຄ່າຕັ້ງແຕ່ 1 ຫາ 19, ຕາມຕາຕະລາງຕໍ່ໄປນີ້.

ດັດສະນີຟັງຊັນ | ຟັງຊັນທີ່ນຳໃຊ້
--- | ---
1 | AVERAGE (ຄ່າສະເລ່ຍ)
2 | COUNT (ນັບຈຳນວນ)
3 | COUNTA (ນັບຄ່າ)
4 | MAX (ຄ່າສູງສຸດ)
5 | MIN (ຄ່າຕ່ຳສຸດ)
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SUM
10 | VAR.S
11 | VAR.P
12 | MEDIAN
13 | MODE.SNGL
14 | LARGE
15 | SMALL
16 | PERCENTILE.INC
17 | QUARTILE.INC
18 | PERCENTILE.EXC
19 | QUARTILE.EXC

ສຳລັບອາກິວເມນທີ່ເປັນຈຳນວນຖ້ວນ, ຄ່າທີ່ບໍ່ແມ່ນຈຳນວນຖ້ວນຈະຖືກຕັດເສດໃຫ້ເປັນຈຳນວນຖ້ວນ.

Option – ອາກິວເມັນທີ່ຈຳເປັນ. ດັດຊະນີຕົວເລືອກ ຫຼື ການອ້າງອີງໃສ່ເຊວທີ່ມີຄ່າຕັ້ງແຕ່ 0 ຫາ 7 ເພື່ອກຳນົດວ່າຈະລະເວັ້ນຫຍັງໃນຊ່ວງສຳລັບຟັງຊັນ.

ດັດຊະນີຕົວເລືອກ | ຕົວເລືອກທີ່ນຳໃຊ້
--- | ---
0 | ລະເວັ້ນສະເພາະຟັງຊັນ SUBTOTAL ແລະ AGGREGATE ທີ່ຊ້ອນກັນ
1 | ລະເວັ້ນສະເພາະແຖວທີ່ເຊື່ອງໄວ້, ຟັງຊັນ SUBTOTAL ແລະ AGGREGATE ທີ່ຊ້ອນກັນ
2 | ລະເວັ້ນສະເພາະຂໍ້ຜິດພາດ, ຟັງຊັນ SUBTOTAL ແລະ AGGREGATE ທີ່ຊ້ອນກັນ
3 | ລະເວັ້ນແຖວທີ່ເຊື່ອງໄວ້, ຂໍ້ຜິດພາດ, ຟັງຊັນ SUBTOTAL ແລະ AGGREGATE ທີ່ຊ້ອນກັນ
4 | ບໍ່ລະເວັ້ນຫຍັງເລີຍ
5 | ລະເວັ້ນສະເພາະແຖວທີ່ເຊື່ອງໄວ້
6 | ລະເວັ້ນສະເພາະຂໍ້ຜິດພາດ
7 | ລະເວັ້ນສະເພາະແຖວທີ່ເຊື່ອງໄວ້ ແລະ ຂໍ້ຜິດພາດ

ສຳລັບອາກິວເມນທີ່ເປັນຈຳນວນຖ້ວນ, ຄ່າທີ່ບໍ່ແມ່ນຈຳນວນຖ້ວນຈະຖືກຕັດເສດໃຫ້ເປັນຈຳນວນຖ້ວນ.

Number1 – ອາກິວເມັນທີ່ຈຳເປັນ. ອາກິວເມັນຕົວເລກທຳອິດ (ຖ້າຊ່ວງຖືກກຳນົດໂດຍລາຍການຄ່າພາຍໃນຟັງຊັນ) ຫຼື ການອ້າງອີງໃສ່ເຊວທີ່ມີຄ່ານັ້ນ.

Number2, 3, ... – ທາງເລືອກ. ອາກິວເມັນຕົວເລກ ຫຼື ການອ້າງອີງໃສ່ເຊວ (ສູງສຸດ 253 ອາກິວເມັນ), ທີ່ທ່ານຕ້ອງການຄ່າສັງລວມ.

Array – ອາກິວເມັນທີ່ຈຳເປັນ. ອາເຣສາມາດກຳນົດໄດ້ໂດຍຂອບເຂດຂອງຊ່ວງ, ຊື່ຂອງຊ່ວງທີ່ຕັ້ງຊື່ໄວ້ ຫຼື ປ້າຍຊື່ຄໍລຳ.

ສຳລັບການນຳໃຊ້ປ້າຍຊື່ຄໍລຳ, ຕ້ອງເປີດໃຊ້ຟັງຊັນ “ຊອກຫາປ້າຍຊື່ຄໍລຳ ແລະ ແຖວໂດຍອັດຕະໂນມັດ” ກ່ອນ.

k – ອາກິວເມັນທີ່ຈຳເປັນສຳລັບຟັງຊັນດັ່ງນີ້: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. ມັນແມ່ນອາກິວເມັນຕົວເລກ, ເຊິ່ງຕ້ອງກົງກັບອາກິວເມັນທີສອງຂອງຟັງຊັນເຫຼົ່ານີ້.

### ຕົວຢ່າງ

| A | B | C
1 | ຄໍລຳທີໜຶ່ງ | ຄໍລຳທີສອງ | ຄໍລຳທີສາມ
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALUE! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
ສົ່ງຄືນຄ່າສູງສຸດສຳລັບຊ່ວງ A2:A9 = 34.

=AGGREGATE(9;5;A5:C5)
ສົ່ງຄືນຜົນລວມສຳລັບຊ່ວງ A5:C5 = 29, ເຖິງແມ່ນວ່າບາງຄໍລຳຈະຖືກເຊື່ອງໄວ້ກໍຕາມ.

=AGGREGATE(9;5;B2:B9)
ສົ່ງຄືນຜົນລວມຂອງຄໍລຳ B = 115. ຖ້າແຖວໃດນຶ່ງຖືກເຊື່ອງໄວ້, ຟັງຊັນຈະຂ້າມຄ່ານັ້ນໄປ, ຕົວຢ່າງ ຖ້າແຖວທີ 7 ຖືກເຊື່ອງໄວ້, ຟັງຊັນຈະສົ່ງຄືນ 95.

ຖ້າທ່ານຕ້ອງການນຳໃຊ້ຟັງຊັນກັບຊ່ວງແບບ 3D, ຕົວຢ່າງນີ້ຈະສະແດງວິທີການເຮັດ.

=AGGREGATE(13;3;Sheet1.B2:B9:Sheet3.B2:B9)
ຟັງຊັນສົ່ງຄືນຄ່າຖານນິຍົມ (mode) ຂອງຄ່າໃນຄໍລຳທີສອງຜ່ານຊີດ 1 ຫາ 3 (ທີ່ມີຂໍ້ມູນດຽວກັນ) = 8.

ທ່ານສາມາດນຳໃຊ້ການອ້າງອີງໃສ່ເຊວ ຫຼື ຊ່ວງສຳລັບທຸກໆອາກິວເມັນໃນສູດ. ຕົວຢ່າງຕໍ່ໄປນີ້ຈະສະແດງວິທີການເຮັດວຽກຂອງມັນ. ນອກຈາກນັ້ນ, ມັນຍັງສະແດງໃຫ້ເຫັນວ່າທ່ານສາມາດນຳໃຊ້ປ້າຍຊື່ຄໍລຳເພື່ອກຳນົດອາເຣໄດ້.

=AGGREGATE(E3;E5;'ColumnOne')
ຖ້າ E3 = 13 ແລະ E5 = 5, ຟັງຊັນຈະສົ່ງຄືນຄ່າຖານນິຍົມຂອງຄໍລຳທຳອິດ = 10.

#### ຂໍ້ມູນທາງເຕັກນິກ

ຟັງຊັນນີ້ມີໃຫ້ໃຊ້ຕັ້ງແຕ່ LibreOfficeDev 4.4.

ຟັງຊັນນີ້ ບໍ່ແມ່ນ ສ່ວນໜຶ່ງຂອງມາດຕະຖານ Open Document Format for Office Applications (OpenDocument) ເວີຊັນ 1.3 ພາກທີ 4: ຮູບແບບສູດທີ່ຄິດໄລ່ຄືນໃໝ່ (OpenFormula). ຊື່ພື້ນທີ່ (name space) ແມ່ນ

COM.MICROSOFT.AGGREGATE

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ໜ້າວິີກີ AGGREGATE.

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

ຄົ້ນຫາປ້າຍຊື່ຄໍລຳ ແລະ ແຖວໂດຍອັດຕະໂນມັດ

ກະລຸນາສະໜັບສະໜູນພວກເຮົາ!